XVII.	JEDNOTKA  PRINTER

Jednotka Printer je velmi malá. Deklaruje textový soubor Lst, spojí jej s tiskárnou a otevře pro zápis. Po skončení programu, který jednotku Printer používá, je soubor Lst automaticky uzavřen. Jednotka Printer tedy neimplementuje žádné speciální prostředky, pouze ušetří popsané kroky při výstupu textu na tiskárnu.

{======================================================================}
unit Printer;
{======================================================================}

interface

 var Lst: Text;                          { textový soubor, automaticky }
                                         { spojený s tiskárnou         }

implementation

 var NextExitProc: Pointer;              { původní hodnota ExitProc    }

 procedure Uklid; far;                   { úklidová procedura jednotky }
 {--------------}
 begin { Uklid }
  ExitProc := NextExitProc;              { obnovení hodnoty ExitProc   }
  Close (Lst)                            { zavření soboru Lst          }
 end; { Uklid }

begin { Printer }
 Assign (Lst, 'prn');                    { spojení Lst s tiskárnou     }
 Rewrite (Lst);                          { a otevření pro zápis        }
 NextExitProc := ExitProc;               { instalace úklidové          }
 ExitProc := @Uklid                      { procedury                   }
end. { Printer }